add noctalia and fuzzel

2026-05-23 21:20:58 +02:00
parent 364801f1a3
commit 9a3eceb3ab
599 changed files with 204318 additions and 0 deletions
@@ -0,0 +1,18 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.Networking
+import qs.Services.UI
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  icon: !NetworkService.airplaneModeEnabled ? "plane-off" : "plane"
+  hot: NetworkService.airplaneModeEnabled
+  tooltipText: I18n.tr("toast.airplane-mode.title")
+  onClicked: {
+    NetworkService.setAirplaneMode(!NetworkService.airplaneModeEnabled);
+  }
+  enabled: NetworkService.wifiAvailable && BluetoothService.bluetoothAvailable
+}
@@ -0,0 +1,23 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.Networking
+import qs.Services.UI
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  icon: !BluetoothService.enabled ? "bluetooth-off" : ((BluetoothService.connectedDevices && BluetoothService.connectedDevices.length > 0) ? "bluetooth-connected" : "bluetooth")
+  tooltipText: I18n.tr("common.bluetooth")
+  onClicked: {
+    var p = PanelService.getPanel("bluetoothPanel", screen);
+    if (p)
+      p.toggle(this);
+  }
+  onRightClicked: {
+    if (!NetworkService.airplaneModeEnabled) {
+      BluetoothService.setBluetoothEnabled(!BluetoothService.enabled);
+    }
+  }
+}
@@ -0,0 +1,178 @@
+import QtQuick
+import Quickshell
+import Quickshell.Io
+import qs.Commons
+import qs.Widgets
+
+Item {
+  id: root
+
+  property string widgetId: "CustomButton"
+  property var widgetSettings: null
+
+  property string onClickedCommand: ""
+  property string onRightClickedCommand: ""
+  property string onMiddleClickedCommand: ""
+  property string stateChecksJson: "[]" // Store state checks as JSON string
+
+  property string generalTooltipText: ""
+  property bool enableOnStateLogic: false
+  property bool showExecTooltip: true
+  property bool _hasCustomTooltip: false
+
+  property string _currentIcon: "heart" // Default icon
+  property bool _isHot: false
+  property var _parsedStateChecks: [] // Local array for parsed state checks
+
+  property int _currentStateCheckIndex: -1
+  property string _activeStateIcon: ""
+
+  implicitWidth: button.implicitWidth
+  implicitHeight: button.implicitHeight
+
+  Connections {
+    target: root
+
+    function _updatePropertiesFromSettings() {
+      if (!widgetSettings) {
+        return;
+      }
+
+      onClickedCommand = widgetSettings.onClicked || "";
+      onRightClickedCommand = widgetSettings.onRightClicked || "";
+      onMiddleClickedCommand = widgetSettings.onMiddleClicked || "";
+      stateChecksJson = widgetSettings.stateChecksJson || "[]"; // Populate from widgetSettings
+      try {
+        _parsedStateChecks = JSON.parse(stateChecksJson);
+      } catch (e) {
+        Logger.e("CustomButton", "Failed to parse stateChecksJson:", e.message);
+        _parsedStateChecks = [];
+      }
+      generalTooltipText = widgetSettings.generalTooltipText || "";
+      _hasCustomTooltip = !!(widgetSettings.generalTooltipText && widgetSettings.generalTooltipText.trim() !== "");
+      enableOnStateLogic = widgetSettings.enableOnStateLogic || false;
+      showExecTooltip = widgetSettings.showExecTooltip !== undefined ? widgetSettings.showExecTooltip : true;
+
+      updateState();
+    }
+
+    function onWidgetSettingsChanged() {
+      if (widgetSettings) {
+        _updatePropertiesFromSettings();
+      }
+    }
+  }
+
+  Process {
+    id: stateCheckProcessExecutor
+    running: false
+    command: _currentStateCheckIndex !== -1 && _parsedStateChecks.length > _currentStateCheckIndex ? ["sh", "-lc", _parsedStateChecks[_currentStateCheckIndex].command] : []
+    onExited: function (exitCode, stdout, stderr) {
+      var currentCheckItem = _parsedStateChecks[_currentStateCheckIndex];
+      var currentCommand = currentCheckItem.command;
+      if (exitCode === 0) {
+        // Command succeeded, this is the active state
+        _isHot = true;
+        _activeStateIcon = currentCheckItem.icon || widgetSettings.icon || "heart";
+      } else {
+        // Command failed, try next one
+        _currentStateCheckIndex++;
+        _checkNextState();
+      }
+    }
+  }
+
+  Timer {
+    id: stateUpdateTimer
+    interval: 200
+    running: false
+    repeat: false
+    onTriggered: {
+      if (enableOnStateLogic && _parsedStateChecks.length > 0) {
+        _currentStateCheckIndex = 0;
+        _checkNextState();
+      } else {
+        _isHot = false;
+        _activeStateIcon = widgetSettings.icon || "heart";
+      }
+    }
+  }
+
+  function _checkNextState() {
+    if (_currentStateCheckIndex < _parsedStateChecks.length) {
+      var currentCheckItem = _parsedStateChecks[_currentStateCheckIndex];
+      if (currentCheckItem && currentCheckItem.command) {
+        stateCheckProcessExecutor.running = true;
+      } else {
+        _currentStateCheckIndex++;
+        _checkNextState();
+      }
+    } else {
+      // All checks failed
+      _isHot = false;
+      _activeStateIcon = widgetSettings.icon || "heart";
+    }
+  }
+
+  function updateState() {
+    if (!enableOnStateLogic || _parsedStateChecks.length === 0) {
+      _isHot = false;
+      _activeStateIcon = widgetSettings.icon || "heart";
+      return;
+    }
+    stateUpdateTimer.restart();
+  }
+
+  function _buildTooltipText() {
+    // Build tooltip based on settings
+    let tooltip = "";
+
+    // If user set custom text, always show it
+    // If no custom text and showExecTooltip is off, show i18n default
+    if (_hasCustomTooltip) {
+      tooltip = generalTooltipText;
+    } else if (!showExecTooltip) {
+      tooltip = I18n.tr("bar.custom-button.default-tooltip");
+    }
+
+    // Add command details if enabled
+    if (showExecTooltip) {
+      if (onClickedCommand) {
+        tooltip += (tooltip ? "\n" : "") + I18n.tr("bar.custom-button.left-click-label") + `: ${onClickedCommand}`;
+      }
+      if (onRightClickedCommand) {
+        tooltip += (tooltip ? "\n" : "") + I18n.tr("bar.custom-button.right-click-label") + `: ${onRightClickedCommand}`;
+      }
+      if (onMiddleClickedCommand) {
+        tooltip += (tooltip ? "\n" : "") + I18n.tr("bar.custom-button.middle-click-label") + `: ${onMiddleClickedCommand}`;
+      }
+    }
+
+    return tooltip;
+  }
+
+  NIconButtonHot {
+    id: button
+    icon: _activeStateIcon
+    hot: _isHot
+    tooltipText: _buildTooltipText()
+    onClicked: {
+      if (onClickedCommand) {
+        Quickshell.execDetached(["sh", "-lc", onClickedCommand]);
+        updateState();
+      }
+    }
+    onRightClicked: {
+      if (onRightClickedCommand) {
+        Quickshell.execDetached(["sh", "-lc", onRightClickedCommand]);
+        updateState();
+      }
+    }
+    onMiddleClicked: {
+      if (onMiddleClickedCommand) {
+        Quickshell.execDetached(["sh", "-lc", onMiddleClickedCommand]);
+        updateState();
+      }
+    }
+  }
+}
@@ -0,0 +1,13 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.Power
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  icon: "dark-mode"
+  tooltipText: Settings.data.colorSchemes.darkMode ? I18n.tr("tooltips.switch-to-light-mode") : I18n.tr("tooltips.switch-to-dark-mode")
+  onClicked: Settings.data.colorSchemes.darkMode = !Settings.data.colorSchemes.darkMode
+}
@@ -0,0 +1,14 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.Power
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  icon: IdleInhibitorService.isInhibited ? "keep-awake-on" : "keep-awake-off"
+  hot: IdleInhibitorService.isInhibited
+  tooltipText: I18n.tr("tooltips.keep-awake")
+  onClicked: IdleInhibitorService.manualToggle()
+}
@@ -0,0 +1,21 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.Networking
+import qs.Services.UI
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+  icon: NetworkService.getIcon()
+  tooltipText: NetworkService.getStatusText(true)
+  onClicked: {
+    var panel = PanelService.getPanel("networkPanel", screen);
+    panel?.toggle(this);
+  }
+  onRightClicked: {
+    if (!NetworkService.airplaneModeEnabled) {
+      NetworkService.setWifiEnabled(!NetworkService.wifiEnabled);
+    }
+  }
+}
@@ -0,0 +1,34 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Modules.Panels.Settings
+import qs.Services.System
+import qs.Services.UI
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  enabled: ProgramCheckerService.wlsunsetAvailable
+  icon: Settings.data.nightLight.enabled ? (Settings.data.nightLight.forced ? "nightlight-forced" : "nightlight-on") : "nightlight-off"
+  hot: Settings.data.nightLight.enabled
+  tooltipText: I18n.tr("common.night-light")
+
+  onClicked: {
+    if (!Settings.data.nightLight.enabled) {
+      Settings.data.nightLight.enabled = true;
+      Settings.data.nightLight.forced = false;
+    } else if (Settings.data.nightLight.enabled && !Settings.data.nightLight.forced) {
+      Settings.data.nightLight.forced = true;
+    } else {
+      Settings.data.nightLight.enabled = false;
+      Settings.data.nightLight.forced = false;
+    }
+  }
+
+  onRightClicked: {
+    var settingsPanel = PanelService.getPanel("settingsPanel", screen);
+    settingsPanel.requestedTab = SettingsPanel.Tab.Display;
+    settingsPanel.open();
+  }
+}
@@ -0,0 +1,14 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.Power
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  icon: PowerProfileService.noctaliaPerformanceMode ? "rocket" : "rocket-off"
+  tooltipText: I18n.tr("tooltips.noctalia-performance-enabled")
+  hot: PowerProfileService.noctaliaPerformanceMode
+  onClicked: PowerProfileService.toggleNoctaliaPerformance()
+}
@@ -0,0 +1,16 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.System
+import qs.Services.UI
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  icon: NotificationService.doNotDisturb ? "bell-off" : "bell"
+  hot: NotificationService.doNotDisturb
+  tooltipText: I18n.tr("common.notifications")
+  onClicked: PanelService.getPanel("notificationHistoryPanel", screen)?.toggle(this)
+  onRightClicked: NotificationService.doNotDisturb = !NotificationService.doNotDisturb
+}
@@ -0,0 +1,19 @@
+import QtQuick.Layouts
+import Quickshell
+import Quickshell.Services.UPower
+import qs.Commons
+import qs.Services.Power
+import qs.Widgets
+
+// Performance
+NIconButtonHot {
+  property ShellScreen screen
+
+  readonly property bool hasPP: PowerProfileService.available
+
+  enabled: hasPP
+  icon: PowerProfileService.getIcon()
+  hot: !PowerProfileService.isDefault()
+  tooltipText: I18n.tr("control-center.power-profile.tooltip-action")
+  onClicked: PowerProfileService.cycleProfile()
+}
@@ -0,0 +1,15 @@
+import QtQuick.Layouts
+import Quickshell
+import qs.Commons
+import qs.Services.UI
+import qs.Widgets
+
+NIconButtonHot {
+  property ShellScreen screen
+
+  enabled: Settings.data.wallpaper.enabled
+  icon: "wallpaper-selector"
+  tooltipText: I18n.tr("wallpaper.panel.title")
+  onClicked: PanelService.getPanel("wallpaperPanel", screen)?.toggle()
+  onRightClicked: WallpaperService.setRandomWallpaper()
+}